SkullCyberArmy Bypass Shell - mail.destinationexplore.in

Uname : Linux serv1.rebootns.com 5.14.0-570.62.1.el9_6.x86_64 #1 SMP PREEMPT_DYNAMIC Tue Nov 11 10:10:59 EST 2025 x86_64
Soft : LiteSpeed
Ip : 139.99.125.122
Port : 443

Grammar.txt

# Grammar for 2to3. This grammar supports Python 2.x and 3.x.

# Note:  Changing the grammar specified in this file will most likely
#        require corresponding changes in the parser module
#        (../Modules/parsermodule.c).  If you can't make the changes to
#        that module yourself, please co-ordinate the required changes
#        with someone who can; ask around on python-dev for help.  Fred
#        Drake <fdrake@acm.org> will probably be listening there.

# NOTE WELL: You should also follow all the steps listed in PEP 306,
# "How to Change Python's Grammar"

# Commands for Kees Blom's railroad program
#diagram:token NAME
#diagram:token NUMBER
#diagram:token STRING
#diagram:token NEWLINE
#diagram:token ENDMARKER
#diagram:token INDENT
#diagram:output\input python.bla
#diagram:token DEDENT
#diagram:output\textwidth 20.04cm\oddsidemargin  0.0cm\evensidemargin 0.0cm
#diagram:rules

# Start symbols for the grammar:
#	file_input is a module or sequence of commands read from an input file;
#	single_input is a single interactive statement;
#	eval_input is the input for the eval() and input() functions.
# NB: compound_stmt in single_input is followed by extra NEWLINE!
file_input: (NEWLINE | stmt)* ENDMARKER
single_input: NEWLINE | simple_stmt | compound_stmt NEWLINE
eval_input: testlist NEWLINE* ENDMARKER

decorator: '@' dotted_name [ '(' [arglist] ')' ] NEWLINE
decorators: decorator+
decorated: decorators (classdef | funcdef)
funcdef: 'def' NAME parameters ['->' test] ':' suite
parameters: '(' [typedargslist] ')'
typedargslist: ((tfpdef ['=' test] ',')*
                ('*' [tname] (',' tname ['=' test])* [',' '**' tname] | '**' tname)
                | tfpdef ['=' test] (',' tfpdef ['=' test])* [','])
tname: NAME [':' test]
tfpdef: tname | '(' tfplist ')'
tfplist: tfpdef (',' tfpdef)* [',']
varargslist: ((vfpdef ['=' test] ',')*
              ('*' [vname] (',' vname ['=' test])*  [',' '**' vname] | '**' vname)
              | vfpdef ['=' test] (',' vfpdef ['=' test])* [','])
vname: NAME
vfpdef: vname | '(' vfplist ')'
vfplist: vfpdef (',' vfpdef)* [',']

compound_stmt: if_stmt | while_stmt | for_stmt | try_stmt | with_stmt | funcdef | classdef | decorated
if_stmt: 'if' test ':' suite ('elif' test ':' suite)* ['else' ':' suite]
while_stmt: 'while' test ':' suite ['else' ':' suite]
for_stmt: 'for' exprlist 'in' testlist ':' suite ['else' ':' suite]
try_stmt: ('try' ':' suite
           ((except_clause ':' suite)+
	    ['else' ':' suite]
	    ['finally' ':' suite] |
	   'finally' ':' suite))
with_stmt: 'with' with_item (',' with_item)*  ':' suite
with_item: test ['as' expr]
with_var: 'as' expr
# NB compile.c makes sure that the default except clause is last
except_clause: 'except' [test [(',' | 'as') test]]
suite: simple_stmt | NEWLINE INDENT stmt+ DEDENT

# Backward compatibility cruft to support:
# [ x for x in lambda: True, lambda: False if x() ]
# even while also allowing:
# lambda x: 5 if x else 2
# (But not a mix of the two)
testlist_safe: old_test [(',' old_test)+ [',']]
old_test: or_test | old_lambdef
old_lambdef: 'lambda' [varargslist] ':' old_test

test: or_test ['if' or_test 'else' test] | lambdef
or_test: and_test ('or' and_test)*
and_test: not_test ('and' not_test)*
not_test: 'not' not_test | comparison
comparison: expr (comp_op expr)*
comp_op: '<'|'>'|'=='|'>='|'<='|'<>'|'!='|'in'|'not' 'in'|'is'|'is' 'not'
star_expr: '*' expr
expr: xor_expr ('|' xor_expr)*
xor_expr: and_expr ('^' and_expr)*
and_expr: shift_expr ('&' shift_expr)*
shift_expr: arith_expr (('<<'|'>>') arith_expr)*
arith_expr: term (('+'|'-') term)*
term: factor (('*'|'@'|'/'|'%'|'//') factor)*
factor: ('+'|'-'|'~') factor | power
power: atom trailer* ['**' factor]
atom: ('(' [yield_expr|testlist_gexp] ')' |
       '[' [listmaker] ']' |
       '{' [dictsetmaker] '}' |
       '`' testlist1 '`' |
       NAME | NUMBER | STRING+ | '.' '.' '.')
listmaker: (test|star_expr) ( comp_for | (',' (test|star_expr))* [','] )
testlist_gexp: (test|star_expr) ( comp_for | (',' (test|star_expr))* [','] )
lambdef: 'lambda' [varargslist] ':' test
trailer: '(' [arglist] ')' | '[' subscriptlist ']' | '.' NAME
subscriptlist: subscript (',' subscript)* [',']
subscript: test | [test] ':' [test] [sliceop]
sliceop: ':' [test]
exprlist: (expr|star_expr) (',' (expr|star_expr))* [',']
testlist: test (',' test)* [',']
dictsetmaker: ( ((test ':' test | '**' expr)
                 (comp_for | (',' (test ':' test | '**' expr))* [','])) |
                ((test | star_expr)
		 (comp_for | (',' (test | star_expr))* [','])) )

classdef: 'class' NAME ['(' [arglist] ')'] ':' suite

arglist: argument (',' argument)* [',']

# "test '=' test" is really "keyword '=' test", but we have no such token.
# These need to be in a single rule to avoid grammar that is ambiguous
# to our LL(1) parser. Even though 'test' includes '*expr' in star_expr,
# we explicitly match '*' here, too, to give it proper precedence.
# Illegal combinations and orderings are blocked in ast.c:
# multiple (test comp_for) arguments are blocked; keyword unpackings
# that precede iterable unpackings are blocked; etc.
argument: ( test [comp_for] |
            test '=' test |
	    '**' expr |
	    star_expr )

comp_iter: comp_for | comp_if
comp_for: 'for' exprlist 'in' testlist_safe [comp_iter]
comp_if: 'if' old_test [comp_iter]

testlist1: test (',' test)*

# not used in grammar, but may appear in "node" passed from Parser to Compiler
encoding_decl: NAME

yield_expr: 'yield' [yield_arg]
yield_arg: 'from' test | testlist

Name	Type	Size	Permission	Last Modified	Actions
.	dir	-	0755	2025-11-16 11:16:00
..	dir	-	0755	2025-11-16 11:26:58
fixes	dir	-	0755	2025-11-16 11:16:00
pgen2	dir	-	0755	2025-11-16 11:16:00
Grammar.txt	file	6.93 KB	0644	2025-01-08 10:54:04
Grammar2.7.18.final.0.pickle	file	39.54 KB	0644	2025-01-08 10:54:04
PatternGrammar.txt	file	793 B	0644	2025-01-08 10:54:03
PatternGrammar2.7.18.final.0.pickle	file	2.73 KB	0644	2025-01-08 10:54:03
__init__.py	file	7 B	0644	2025-01-08 10:54:04
__init__.pyc	file	140 B	0644	2025-01-08 10:54:04
__init__.pyo	file	140 B	0644	2025-01-08 10:54:04
__main__.py	file	67 B	0644	2025-01-08 10:54:04
__main__.pyc	file	255 B	0644	2025-01-08 10:54:03
__main__.pyo	file	255 B	0644	2025-01-08 10:54:03
btm_matcher.py	file	6.67 KB	0644	2025-01-08 10:54:04
btm_matcher.pyc	file	5.83 KB	0644	2025-01-08 10:54:04
btm_matcher.pyo	file	5.83 KB	0644	2025-01-08 10:54:04
btm_utils.py	file	9.78 KB	0644	2025-01-08 10:54:03
btm_utils.pyc	file	7.55 KB	0644	2025-01-08 10:54:04
btm_utils.pyo	file	7.55 KB	0644	2025-01-08 10:54:04
fixer_base.py	file	6.62 KB	0644	2025-01-08 10:54:04
fixer_base.pyc	file	7.22 KB	0644	2025-01-08 10:54:04
fixer_base.pyo	file	7.22 KB	0644	2025-01-08 10:54:04
fixer_util.py	file	14.25 KB	0644	2025-01-08 10:54:04
fixer_util.pyc	file	14.77 KB	0644	2025-01-08 10:54:04
fixer_util.pyo	file	14.77 KB	0644	2025-01-08 10:54:04
main.py	file	11.33 KB	0644	2025-01-08 10:54:03
main.pyc	file	9.73 KB	0644	2025-01-08 10:54:04
main.pyo	file	9.69 KB	0644	2025-01-08 10:54:04
patcomp.py	file	6.9 KB	0644	2025-01-08 10:54:03
patcomp.pyc	file	6.6 KB	0644	2025-01-08 10:54:04
patcomp.pyo	file	6.29 KB	0644	2025-01-08 10:54:04
pygram.py	file	1.13 KB	0644	2025-01-08 10:54:04
pygram.pyc	file	1.45 KB	0644	2025-01-08 10:54:04
pygram.pyo	file	1.45 KB	0644	2025-01-08 10:54:04
pytree.py	file	28.36 KB	0644	2025-01-08 10:54:04
pytree.pyc	file	30.56 KB	0644	2025-01-08 10:54:04
pytree.pyo	file	29.7 KB	0644	2025-01-08 10:54:04
refactor.py	file	27.37 KB	0644	2025-01-08 10:54:03
refactor.pyc	file	23.87 KB	0644	2025-01-08 10:54:04
refactor.pyo	file	23.83 KB	0644	2025-01-08 10:54:04